
AshRateLimiter
Welcome! This is an extension for the Ash framework
which protects actions from abuse by enforcing rate limits.
Uses the excellent hammer to provide rate limiting functionality.
Installation
Using Igniter (Recommended)
The easiest way to install ash_rate_limiter is using Igniter:
mix igniter.install ash_rate_limiter

This will:
	Add the dependency to your mix.exs
	Configure the formatter to handle AshRateLimiter DSL
	Set up proper Spark DSL section ordering

Manual Installation
Add ash_rate_limiter to your list of dependencies in mix.exs:
def deps do
  [
    {:ash_rate_limiter, "~> 2.0.1"}
  ]
end
And add :ash_rate_limiter to your .formatter.exs:
[
  import_deps: [:ash, :ash_rate_limiter],
  # ... other formatter config
]
Quick Start
	Add a Hammer module: You need to create a Hammer module:

# lib/my_app/hammer.ex
defmodule MyApp.Hammer do
  use Hammer, backend: :ets
end
	Add the rate limiter to your application's supervision tree: (more information about :clean_period in Hammer):

# lib/my_app/application.ex
  @impl true
  def start(_type, _args) do
    children = [
      # ...
      # Add the line below:
      {MyApp.Hammer, clean_period: :timer.minutes(1)},
      # ...
    ]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end
	Configure the Hammer backend Add configuration to point to your Hammer module:

# config/config.exs
config :my_app, :ash_rate_limiter,
  hammer: MyApp.Hammer
	Add to your resource: Use the rate_limit DSL section in your Ash resource:

defmodule MyApp.Post do
  use Ash.Resource,
    domain: MyApp,
    extensions: [AshRateLimiter]

  rate_limit do
    # Configure hammer backend
    backend MyApp.Hammer
    
    # Limit create action to 10 requests per 5 minutes
    action :create, limit: 10, per: :timer.minutes(5)
    
    # Limit read action to 100 requests per minute  
    action :read, limit: 100, per: :timer.minutes(1)
  end

  # ... rest of your resource definition
end
	That's it! Your actions are now rate limited. When the limit is exceeded, an AshRateLimiter.LimitExceeded error will be raised.

Basic Usage
Simple Rate Limiting
rate_limit do
  backend MyApp.Hammer
  action :create, limit: 5, per: :timer.minutes(1)
end
Per-User Rate Limiting
rate_limit do
  backend MyApp.Hammer
  action :create, 
    limit: 10, 
    per: :timer.minutes(5),
    key: fn changeset, context ->
      "user:#{context.actor.id}:create"
    end
end
Multiple Actions
rate_limit do
  backend MyApp.Hammer
  action :create, limit: 10, per: :timer.minutes(5)
  action :update, limit: 20, per: :timer.minutes(5) 
  action :read, limit: 100, per: :timer.minutes(1)
end
Advanced Usage
Manual Integration
For more control, you can add rate limiting directly to specific actions:
defmodule MyApp.Post do
  use Ash.Resource, domain: MyApp

  actions do
    create :create do
      change {AshRateLimiter.Change, limit: 10, per: :timer.minutes(5)}
    end
    
    read :read do
      prepare {AshRateLimiter.Preparation, limit: 100, per: :timer.minutes(1)}
    end
  end
end
Custom Key Functions
The key function determines how requests are grouped for rate limiting:
# Rate limit per IP address
key: fn _changeset, context ->
  "ip:#{context[:ip_address]}"
end

# Rate limit per user and action
key: fn changeset, context ->
  "user:#{context.actor.id}:action:#{changeset.action.name}"
end

# Use the built-in key function with options
key: {&AshRateLimiter.key_for_action/2, include_actor_attributes: [:role]}
Error Handling
When rate limits are exceeded, an AshRateLimiter.LimitExceeded exception is raised:
case MyApp.create_post(attrs) do
  {:ok, post} -> 
    # Success
    {:ok, post}
    
  {:error, %AshRateLimiter.LimitExceeded{} = error} ->
    # Rate limit exceeded
    {:error, "Too many requests, please try again later"}
    
  {:error, other_error} ->
    # Handle other errors
    {:error, other_error}
end
In web applications, the exception includes Plug.Exception behaviour for automatic HTTP 429 responses.
Reference
	AshRateLimiter DSL
	Hammer Documentation



  

    Change Log

All notable changes to this project will be documented in this file.
See Conventional Commits for commit guidelines.
v2.0.1 (2026-08-17)
	no-feature release because of retired 2.0.0 release.

v1.0.0 (2026-02-11)
Breaking Changes:
	make rate limiter backend-pluggable with configurable lifecycle hooks (#62) by adamtharani

	make rate limiter backend-pluggable with configurable lifecycle hooks by adamtharani


Features:
	add hammer dep to igniter installer and create upgrade task by James Harton

Bug Fixes:
	rename hammer to backend in installer and upgrader by James Harton

	replace Hammer with deterministic counting backend in tests by James Harton


v0.2.1 (2026-01-13)
Improvements:
	add generic action support. (#56) by wjrtz

v0.2.0 (2025-10-20)
Features:
	Adding support for igniter install (#48) by srikanthkyatham

	Adding support for igniter install by srikanthkyatham


Bug Fixes:
	add install tests by srikanthkyatham

	only apply changes and preparations to configured actions (#39) by ChristianAlexander


v0.1.1 (2025-05-31)
v0.1.0 (2025-05-21)


  

    AshRateLimiter

An extension for Ash.Resource which adds the ability to rate limit access to actions.
rate_limit
Configure rate limiting for actions.
Backend
This library uses a pluggable backend for rate limiting. Any module implementing the
AshRateLimiter.Backend behaviour can be used. See AshRateLimiter.Backend for more information.
Keys
The backend uses a "key" to identify which bucket to allocate an event against.  You can use this to tune the rate limit for specific users or events.
You can provide either a statically configured string key, or a function of arity one or two, which when given a query/changeset and optional context object can generate a key.
The default is AshRateLimiter.key_for_action/2. See it's docs for more information.
Nested DSLs
	action

Examples
rate_limit do
  backend MyApp.RateLimiter
  action :create, limit: 10, per: :timer.minutes(5)
end

Options
	Name	Type	Default	Docs
	backend	module		The rate limiting backend module

rate_limit.action
action action
Configure rate limiting for a single action.
It does this by adding a global change or preparation to the resource with the provided configuration.  For more advanced configuration you can add the change/preparation directly to your action using AshRateLimiter.BuiltinChanges.rate_limit/1 or AshRateLimiter.BuiltinPreparations.rate_limit/1.
Arguments
	Name	Type	Default	Docs
	action	atom		The name of the action to limit

Options
	Name	Type	Default	Docs
	limit	pos_integer		The maximum number of events allowed within the given period
	per	pos_integer		The time period (in milliseconds) for in which events are counted
	key	String.t | (any -> any) | (any, any -> any)	&AshRateLimiter.key_for_action/2	The key used to identify the event. See above.
	description	String.t		A description of the rate limit
	on	:before_action | :before_transaction	:before_action	The lifecycle hook to use for rate limiting. :before_action (default) runs inside the transaction; :before_transaction runs outside the transaction, after validations.

Introspection
Target: AshRateLimiter

An extension for Ash.Resource which adds the ability to rate limit access to actions.

          @type keyfun() ::
  (Ash.Query.t() | Ash.Changeset.t() | Ash.ActionInput.t() -> String.t())
  | (Ash.Query.t() | Ash.Changeset.t() | Ash.ActionInput.t(), map() ->
       String.t())

          @type t() :: %AshRateLimiter{
  __identifier__: any(),
  __spark_metadata__: Spark.Dsl.Entity.spark_meta(),
  action: atom(),
  description: nil | String.t(),
  key: String.t() | keyfun(),
  limit: pos_integer(),
  on: term(),
  per: pos_integer() | Duration.t()
}

          @spec key_for_action(
  Ash.Query.t() | Ash.Changeset.t() | Ash.ActionInput.t(),
  map(),
  keyword()
) ::
  String.t()


      


The default bucket key generation function for AshRateLimiter.
Generates a key based on the domain, resource and action names. For update and destroy actions it will also include the primary key(s) in the key.
Works with Ash.Query, Ash.Changeset, and Ash.ActionInput (for generic actions).
Options
	:include_pk? (boolean/0) - Whether or not to include the primary keys in the generated key in update/destroy actions. The default value is true.

	:include_actor_attributes (one or a list of atom/0) - A list of attributes to include from the current actor The default value is [].

	:include_tenant? (boolean/0) - Whether or not to include the tenant in the bucket key. The default value is false.


Examples
iex> Example.Post
...> |> Ash.Changeset.for_create(:create, post_attrs())
...> |> key_for_action(%{})
"example/post/create"

iex> Example.Post
...> |> Ash.Query.for_read(:read)
...> |> key_for_action(%{})
"example/post/read"

iex> generate_post(id: "0196ebc0-83b4-7938-bc9d-22ae65dbec0b")
...> |> Ash.Changeset.for_update(:update, %{title: "Local Farmer Claims 'Space Zombie' Wrecked His Barn"})
...> |> key_for_action(%{})
"example/post/update?id=0196ebc0-83b4-7938-bc9d-22ae65dbec0b"

iex> generate_post(id: "0196ebc6-4839-7a9e-b2a6-feb0eabc8772")
...> |> Ash.Changeset.for_destroy(:destroy)
...> |> key_for_action(%{})
"example/post/destroy?id=0196ebc6-4839-7a9e-b2a6-feb0eabc8772"

iex> generate_post(id: "0196ebcd-fabf-74c3-9585-8b13c5f07068")
...> |> Ash.Changeset.for_destroy(:destroy)
...> |> key_for_action(%{}, include_pk?: false)
"example/post/destroy"

iex> Example.Post
...> |> Ash.Changeset.for_create(:create, post_attrs())
...> |> key_for_action(%{actor: %{role: :time_traveller}}, include_actor_attributes: [:role])
"example/post/create?actor%5Brole%5D=time_traveller"

iex> Example.Post
...> |> Ash.Changeset.new()
...> |> Ash.Changeset.set_tenant("Hill Valley Telegraph")
...> |> Ash.Changeset.for_create(:create, post_attrs())
...> |> key_for_action(%{}, include_tenant?: true)
"example/post/create?tenant=Hill%20Valley%20Telegraph"

A behaviour for rate limiting backends.
Implement this behaviour to provide a custom rate limiting backend for use with AshRateLimiter.
Example
defmodule MyApp.RateLimiter do
  @behaviour AshRateLimiter.Backend

  @impl true
  def hit(key, window_ms, limit) do
    # Your rate limiting logic here
    {:allow, 1}
  end
end

          @callback hit(key :: String.t(), window_ms :: pos_integer(), limit :: pos_integer()) ::
  {:allow, pos_integer()} | {:deny, pos_integer()}

Change helpers to allow direct usage in mutation actions.

        Add a rate-limit change directly to an action.

          @type rate_limit_options() :: [
  limit: pos_integer(),
  per: pos_integer(),
  key: String.t() | AshRateLimiter.keyfun(),
  on: :before_action | :before_transaction
]

          @spec rate_limit(rate_limit_options()) ::
  {AshRateLimiter.Change, rate_limit_options()}


      


Add a rate-limit change directly to an action.
Options
	:limit (pos_integer/0) - Required. The maximum number of events allowed within the given scale

	:per (pos_integer/0) - Required. The time period (in milliseconds) for in which events are counted

	:key - The key used to identify the event. See the docs for AshRateLimiter.key_for_action/2 for more. The default value is &AshRateLimiter.key_for_action/2.

	:on - The lifecycle hook to use for rate limiting. :before_action runs inside the transaction; :before_transaction runs outside the transaction, after validations. Valid values are :before_action, :before_transaction The default value is :before_action.

Preparation helpers to allow direct usage in read actions.

          @type rate_limit_options() :: [
  limit: pos_integer(),
  per: pos_integer(),
  key: String.t() | AshRateLimiter.keyfun(),
  on: :before_action | :before_transaction
]

          @spec rate_limit(rate_limit_options()) ::
  {AshRateLimiter.Preparation, rate_limit_options()}


      


Add a rate-limit change directly to an action.
Options
	:limit (pos_integer/0) - Required. The maximum number of events allowed within the given scale

	:per (pos_integer/0) - Required. The time period (in milliseconds) for in which events are counted

	:key - The key used to identify the event. See the docs for AshRateLimiter.key_for_action/2 for more. The default value is &AshRateLimiter.key_for_action/2.

	:on - The lifecycle hook to use for rate limiting. :before_action runs inside the transaction; :before_transaction runs outside the transaction, after validations. Valid values are :before_action, :before_transaction The default value is :before_action.

A resource change which implements rate limiting.

Auto-generated introspection functions.

rate_limit DSL entities

          @spec rate_limit_backend(dsl_or_extended :: module() | map()) ::
  {:ok, module()} | :error


      


The rate limiting backend module

          @spec rate_limit_backend!(dsl_or_extended :: module() | map()) ::
  module() | no_return()


      


The rate limiting backend module

          @spec rate_limit_options(dsl_or_extended :: module() | map()) :: %{
  required(atom()) => any()
}


      


rate_limit DSL options
Returns a map containing the and any configured or default values.

A resource preparation which implements rate limiting.
Supports both read actions (via Ash.Query) and generic actions (via Ash.ActionInput).

A Spark DSL transformer for rate limiting.

        Callback implementation for Spark.Dsl.Transformer.after_compile?/0.

        Callback implementation for Spark.Dsl.Transformer.before?/1.

Callback implementation for Spark.Dsl.Transformer.after_compile?/0.

Callback implementation for Spark.Dsl.Transformer.before?/1.

An exception which is raised or returned when an action invocation exceeds the defined limits.

        Create an Elixir.AshRateLimiter.LimitExceeded without raising it.

          @spec exception(opts :: Keyword.t()) :: %AshRateLimiter.LimitExceeded{
  __exception__: true,
  action: term(),
  backend: term(),
  bread_crumbs: term(),
  class: term(),
  key: term(),
  limit: term(),
  path: term(),
  per: term(),
  splode: term(),
  stacktrace: term(),
  vars: term()
}


      


Create an Elixir.AshRateLimiter.LimitExceeded without raising it.
Keys
	:action
	:backend
	:limit
	:per
	:key

